Smithing 106+

Posts: 184
Joined: Fri Feb 19, 2016 9:46 pm

Smithing 106+

Postby Tillblik » Sun Jan 29, 2017 4:14 am

Here is a Macro for smithing starting with plate gloves. I'll eventually edit it to start from 50.

// For this macro to work you must set 3 counters iron ingots format named 'ingots', tinkertools format named 'ttools' and tongs format named 'tongs'.

// Go to Agents (Tab) -> Counters (Tab), click the Insert (Button) and select an item in-game, you can edit its format by double clicking the Format (Field).

Code: Select all
//Go to Agents (Tab) -> Counters (Tab), click the Insert (Button) and select an item in-game, you can edit its format by double clicking the Format (Field).
// For this macro to work you must set 3 counters iron ingots format named ingots, tinkertools format named ttools and tongs format named tongs.
headmsg 'Please select the chest your ingots are in.'
promptalias 'inchest'
while skill 'Blacksmithy' < 120
  //move ingots to backpack
  if counter 'ingots' <= 24
    movetype 0x1bf2 'inchest' 'backpack'0 0 0 0 500
    pause 350
  endif
  usetype 0x1eb8
  replygump 0x38920abd 8
  waitforgump 0x38920abd 2000
  // make 2 tinker tools
  while counter 'ttools' <= 1
    headmsg 'making ttools'
    replygump 0x38920abd 23
    waitforgump 0x38920abd 2000
  endwhile
  // make 2 tongs
  while counter 'tongs' <= 1
    headmsg 'Making tongs'
    replygump 0x38920abd 86
    waitforgump 0x38920abd 2000
  endwhile
  // use tongs and start start smithing
  pause 1000
  usetype 0xfbb
  waitforgump 0x38920abd 2000
  replygump 0x38920abd 15
  waitforgump 0x38920abd 2000
  while counter 'tongs' >= 2
    if counter 'ingots' <= 24
      break
    endif
    //     Platemail Gloves
    if skill 'Blacksmithy' <= 108.9
      msg 'making Platemail Gloves'
      replygump 0x38920abd 9
      waitforgump 0x38920abd 2000
    elseif skill 'Blacksmithy' <= 116.3
      //     Platemail Arms
      msg 'making Platemail Arms'
      replygump 0x38920abd 2
      waitforgump 0x38920abd 2000
    elseif skill 'Blacksmithy' <= 118.8
      //     Platemail Legs
      msg 'Making Platemail Legs'
      replygump 0x38920abd 23
      waitforgump 0x38920abd 2000
    elseif skill 'Blacksmithy' <= 120.0
      //     Platemail Tunics
      msg 'Making Platemail Tunics'
      replygump 0x38920abd 30
      waitforgump 0x38920abd 2000
    else
      // max skill reached stop wasting ingots.
      stop
    endif
    // smelt gloves
    if @findtype 0x1414 'any' 'backpack'
      msg 'smelt gloves'
      replygump 0x38920abd 14
      waitfortarget 2000
      targettype! 0x1414
      waitforgump 0x38920abd 2000
    endif
    //smelt arms
    if @findtype 0x1410 'any' 'backpack'
      msg 'smelt arms'
      replygump 0x38920abd 14
      waitfortarget 2000
      targettype! 0x1410
      waitforgump 0x38920abd 2000
    endif
    //smelt legs
    if @findtype 0x1411 'any' 'backpack'
      msg 'smelt legs'
      replygump 0x38920abd 14
      waitfortarget 2000
      targettype! 0x1411
      waitforgump 0x38920abd 2000
    endif
    //smelt tunic
    if @findtype 0x1415 'any' 'backpack'
      msg 'smelting Tunic'
      replygump 0x38920abd 14
      waitfortarget 2000
      targettype! 0x1415
      waitforgump 0x38920abd 2000
    endif
  endwhile
endwhile


I think the bugs are worked out, if this is not working please post what it's doing wrong and I'll get a fix.

Return to Macros

Who is online

Users browsing this forum: No registered users and 3 guests

cron